Чтение данных из файла DBF

Для чтения файла DBF можно написать следующую процедуру:

Процедура ПрочитатьФайлDBF(ПутьКФайлу, СоответствиеПолей, ТаблицаЗагрузки) Экспорт
    ФайлDBF = Новый XBase;
    ФайлDBF.Кодировка = КодировкаXBase.OEM;
    ФайлDBF.ОткрытьФайл(ПутьКФайлу,,Истина);
    ФайлDBF.Первая();

    Пока НЕ ФайлDBF.ВКонце() Цикл

        НоваяСтрокаТаблицы = ТаблицаЗагрузки.Добавить();

        Для Каждого ЭлементСоответствия Из СоответствиеПолей Цикл
            Попытка
                НоваяСтрокаТаблицы[ЭлементСоответствия.Ключ] = СокрЛП(ФайлDBF[ЭлементСоответствия.Значение]);
            Исключение
            КонецПопытки;
        КонецЦикла;

        ФайлDBF.Следующая();

    КонецЦикла;

    ФайлDBF.ЗакрытьФайл();

КонецПроцедуры

Перед вызовом процедуры надо либо создать таблицу значений с колонками, либо можно использовать реквизит формы с типом значения ТаблицаЗначений.

Перед вызовом необходимо написать соответствие названия колонок в таблице значений и колонок в файле DBF.

СоответствиеПолей = Новый Соответствие;
СоответствиеПолей.Вставить("Номенклатура", "NOM");
СоответствиеПолей.Вставить("Количество", "KOLICH");
СоответствиеПолей.Вставить("Цена", "PRICE");
СоответствиеПолей.Вставить("Сумма", "SUMMA");

Вызов процедуры выполняем следующей строкой:

ПрочитатьФайлDBF("D:\Выгрузки\Продажи.dbf", СоответствиеПолей, ТаблицаДанных);